GAMS Model Simulator

🖥️ Console KEYN.gms

En attente d'exécution...

📝 Code GAMS

$TITLE MODELE 1x2x1 MODELE KEYNESIEN "BATARD" D'UNE ECONOMIE FERMEE PRODUISANT 1 BIEN ET UTILISANT 2 FACTEURS DE PRODUCTION ET UN SEUL AGENT

$ONTEXT
Modèle d'une économie fermée produisant 1 bien et utilisant 2 facteurs de production et un seul agent.
Les ménages épargnent 20% de tout leur revenu.
La structure initiale du modèle est néoclassique mais on introduit une contrainte de rigidité sur les facteurs de production, ce qui revient à introduire l'effet multiplicateur d'un modèle keynésien
En variante, on analyse l'impact économique d'une augmentation de l'investissement de 50% et l'on constate que l' on obtient les mêmes résultats qu'un modèle keynésien (une augmentation de 5% de l'investissement conduit a une augmentation de 50% du PIB).

$OFFTEXT
Parameter ivm;

IVM    = 1 ;

$ONTEXT

$MODEL:KEN_1S

$SECTORS:
        Y! Niveau d'activité pour le secteur Y

$COMMODITIES:
         PC   ! Indice des prix des biens de consommation
         PK   ! Indice des prix des biens d'investissement
         PL   ! Indice des prix de la rémunération du travail
         RK   ! Indice des prix de la rémunération du capital

$CONSUMERS:
        RA! Le niveau de revenu des consommateurs RA

$AUXILIARY:
         KEYN ! Contrainte de rigidité sur les salaires

$PROD:Y    t:1
        O:PC       Q:80
        O:PK       Q:20
        I:PL       Q:60
        I:RK       Q:40

$DEMAND:RA
        D:PC       Q:80
        E:PK       Q:(-20*IVM)
        E:PL       Q:60               R:KEYN
        E:RK       Q:40               R:KEYN

$CONSTRAINT:KEYN
        PL/PC =E= 1 ;

$REPORT:
        V:Cons         O:PC          PROD:Y
        V:Inv          O:PK          PROD:Y
        V:Emp          I:PL          PROD:Y

$OFFTEXT

$SYSINCLUDE mpsgeset KEN_1S
$INCLUDE KEN_1S.GEN

PC.FX = 1 ;
    KEYN.l = 1 ;

KEN_1S.ITERLIM=0 ;
SOLVE KEN_1S USING MCP;

IVM = 1.5 ;

DISPLAY Cons.l, Inv.l ;

$INCLUDE KEN_1S.GEN
KEN_1S.ITERLIM=2000 ;
SOLVE KEN_1S USING MCP;

DISPLAY Cons.l, Inv.l ;

* Nous constatons que l'introduction d'une contrainte de rigidité sur les salaires et l'endogénéisation de l'offre de travail et de capital de manière à respecter cette
* contrainte conduit à obtenir les mêmes résultats qu'un modèle Keynésien (une
* augmentation de 5% de l'investissement conduit à une augmentation de 50% du PIB.

📊 Simulateur MEGC

📁 Navigation

🖥️ Console KEYN.gms

📝 Code GAMS